*** All of the year specific references are located in the Gepirel.chk,
*** Some variables are passed to the related files
*** using new user defined variable features of EPI6.
***
***
before file
help gepi.hlp 1 5 5 context
define diagnosis _______________ global
end
before record
UNHIDE ALL
end
ID
NoEnter
KEY UNIQUE
END
LASTNAME
HELP GEPI.HLP 2 5 +1 CONTEXT
KEY soundex
BEFORE ENTRY
DEFINE AGEDAYS ##### GLOBAL 0
DEFINE MAGICYEAR ## GLOBAL 93
DEFINE MMWRMAX ## GLOBAL 53
DEFINE SUMMDIS _ global "N"
END
IF LASTNAME = "S"
then
HIDE LASTNAME
HIDE FIRST
HIDE ADDRESS
HIDE CITY
HIDE COUNTY
HIDE COUNTYCODE
HIDE REGION
HIDE ZIPCODE
HIDE BIRTHDATE
HIDE AGE
HIDE AGETYPE
HIDE RACE
HIDE ETHNIC
HIDE SEX
UNHIDE CASECOUNT
Type " This is a Summary data record. " 13 10
summdis = "Y"
goto eventname
ELSE HIDE CASECOUNT
CASECOUNT = 1
endif
mustenter
END
FIRST
HELP GEPI.HLP 3 15 +1 CONTEXT
KEY soundex
AUTOSEARCH LIST SOUNDEX LASTNAME FIRST
END
ADDRESS
HELP GEPI.HLP 4 15 +1 CONTEXT
END
CITY
HELP GEPI.HLP 5 15 +1 CONTEXT
END
COUNTY
HELP GEPI.HLP 6 15 +1 CONTEXT
CodeField COUNTYCODE
Codes CNTYCODE.REC
END
COUNTYCODE
HELP GEPI.HLP 7 5 +1 CONTEXT
CODEFIELD REGION
CODES CNTY-REG.REC
goto region
ENTER
END
REGION
HELP GEPI.HLP 8 5 +1 CONTEXT
NOENTER
END
ZIPCODE
HELP GEPI.HLP 9 5 +1 CONTEXT
END
BIRTHDATE
HELP GEPI.HLP 10 5 +1 CONTEXT
*** WITHOUT 4 DIGIT YEARS, IF OVER 93, HAVE TO ENTER AGE, NOT BIRTHDATE. YECH.
* Range "01/01/00" MMWRSTOP
BEFORE ENTRY
UNHIDE AGE
UNHIDE AGETYPE
END
AFTER ENTRY
IF BIRTHDATE <> .
THEN HIDE AGE
HIDE AGETYPE
ENDIF
END
END
AGE
HELP GEPI.HLP 11 5 +1 CONTEXT
MustEnter
Range 0 130
END
AGETYPE
HELP GEPI.HLP 12 5 +1 CONTEXT
MustEnter
Comment Legal
0 YEARS
1 MONTHS
2 WEEKS
3 DAYS
4 "CENSUS CODED"
9 UNKNOWN
END
AFTER ENTRY
TYPE COMMENT 66 13 31
IF AGETYPE = 9
THEN LET AGE = 999
ENDIF
IF AGETYPE = 1 AND AGE > 11
THEN HELP "ERROR: Use YEARS for AGE > 11 months.\nPress ESC to continue" 30 13
type " " 66 13 31
GOTO age
ENDIF
IF AGETYPE =3 AND AGE > 28
THEN HELP "ERROR: Use MONTHS for AGE > 28 days.\nPress ESC to continue" 30 13
type " " 66 13 31
GOTO age
ENDIF
END
END
RACE
HELP GEPI.HLP 13 5 +1 CONTEXT
MustEnter
Comment Legal
N "NATIVE AMERICAN"
A ASIAN/PACIF.ISL.
B BLACK
W WHITE
O OTHER
U UNKNOWN
END
TYPE COMMENT +2 +0 31
END
ETHNIC
HELP GEPI.HLP 14 5 +1 CONTEXT
MustEnter
Comment Legal
H HISPANIC
N "NOT HISP"
U UNKNOWN
END
TYPE COMMENT +2 +0 31
END
SEX
HELP GEPI.HLP 15 5 +1 CONTEXT
MustEnter
Comment Legal
M MALE
F FEMALE
U UNKNOWN
END
TYPE COMMENT +2 +0 31
END
EVENTNAME
HELP GEPI.HLP 16 5 +1 CONTEXT
CodeField EVENT
Codes discodes.REC
IF Lastname = "S" and (EVENT=10570 or EVENT=10220 or EVENT=10280 or EVENT=10310)
THEN
GOTO CASECOUNT
else
IF Lastname = "S" and (EVENT <> 10570 and EVENT <> 10220 and EVENT <> 10280 and EVENT <> 10310)
THEN
UNHIDE LASTNAME
UNHIDE FIRST
UNHIDE ADDRESS
UNHIDE CITY
UNHIDE COUNTY
UNHIDE COUNTYCODE
UNHIDE REGION
UNHIDE ZIPCODE
UNHIDE BIRTHDATE
UNHIDE AGE
UNHIDE AGETYPE
UNHIDE RACE
UNHIDE ETHNIC
UNHIDE SEX
Help " THIS IS NOT A SUMMARY DISEASE, PLEASE ENTER A NAME \n \n enter 'S' just for summary diseases" 10 5
goto lastname
else
if lastname <> "S" and (EVENT=10570 or EVENT=10220 or EVENT=10280 or EVENT=10310)
THEN
Help " This is a SUMMARY DISEASE, Please enter S in last name" 10 5
GOTO LASTNAME
ENDIF
endif
endif
END
EVENT
HELP GEPI.HLP 17 5 +1 CONTEXT
codefield eventname
noenter
END
CASECOUNT
HELP GEPI.HLP 18 5 +1 CONTEXT
IF SUMMDIS = "N"
THEN CASECOUNT = 1
ELSE
IF EVENT=10570
THEN Help " FLU activity codes are \n \n 0 None\n 1 Sporadic\n 2 Regional \n 3 Widespread \n 9 No report \n \n Please Enter Number" 50 5 keys=01239
IF result = 0
THEN help " You must enter a valid Flu activity code \n if the Event name is FLU ACTIVITY \n <esc> to continue...." 4 10
goto EVENTNAME
ELSE IF result = 5
THEN casecount = 9
ELSE casecount = result - 1
ENDIF
ENDIF
ELSE IF CASECOUNT = .
THEN HELP " You must enter a casecount for this disease. Zero is valid. \n <Esc> to continue.... " 4 10
GOTO EVENTNAME
ENDIF
ENDIF
ENDIF
END
EVENTDATE
HELP GEPI.HLP 20 5 +1 CONTEXT
MUSTENTER
IF SUMMDIS <> "S"
THEN
unhide age
unhide agetype
ENDIF
AFTER ENTRY
IF BIRTHDATE <> .
THEN AGEDAYS = EVENTDATE - BIRTHDATE
IF AGEDAYS < 0
THEN HELP "ERROR:Date of ONSET (EVENTDATE) is before date of BIRTH (BIRTHDATE),\nPress ESC to continue." 9 20
GOTO BIRTHDATE
ELSE LET AGETYPE = 0
TYPE "Year(s) " 66 13 31
LET AGE = AGEDAYS/365.25
IF AGE > 130
THEN AGE = 130
ENDIF
IF AGEDAYS = 365
THEN LET AGE = 1
ENDIF
IF AGEDAYS < 365
THEN LET AGETYPE = 1
LET AGE = AGEDAYS/30.44
TYPE "Month(s) " 66 13 31
ENDIF
IF AGEDAYS < 30.44
THEN TYPE "Day(s) " 66 13 31
LET AGETYPE = 3
LET AGE = AGEDAYS
ENDIF
IF (AGEDAYS = 0)
THEN LET AGE = 1
endif
endif
endif
IF UPDATED < EVENTDATE
THEN
HELP "ERROR: The EVENTDATE entered occurs after \nthe date displayed in UPDATED (system date)\nPlease verify\nPress ESC to continue." 9 20
GOTO EVENTDATE
ENDIF
END
END
EVENTTYPE
HELP GEPI.HLP 19 5 +1 CONTEXT
help " Event Date Type is reported \n as Date Of: \n \n 1 Onset \n 2 Diagnosis \n 3 Lab Test \n 4 Reported County \n 5 Reported State \n 9 Unknown \n \n Please Enter Number" 10 4 keys=123459
if result = 0
then eventtype = eventtype
endif
if result <6 and result >0
then EVENTTYPE = result
endif
if result =6
then EVENTTYPE = 9
endif
enter
Comment Legal
1 "ONSET"
2 DIAGNOSIS
3 "LAB TEST"
4 "REPORT CNTY"
5 "REPORT STATE"
9 UNKNOWN
END
if EVENTTYPE = .
then type " " +2 +0 31
GOTO EVENTDATE
ELSE
IF EVENTTYPE = 1
THEN
TYPE "Onset " +2 +0 31
GOTO EVENTDATE
ELSE
IF EVENTTYPE = 2
THEN
TYPE "Diagnosis " +2 +0 31
GOTO EVENTDATE
ELSE
IF EVENTTYPE = 3
THEN
TYPE "Lab Test " +2 +0 31
GOTO EVENTDATE
ELSE
IF EVENTTYPE = 4
THEN
TYPE "Rep. Cnty" +2 +0 31
GOTO EVENTDATE
ELSE
IF EVENTTYPE = 5
THEN
TYPE "Rep. State " +2 +0 31
GOTO EVENTDATE
ELSE
IF EVENTTYPE = 9
THEN
TYPE "Unknown " +2 +0 31
ENDIF
ENDIF
ENDIF
ENDIF
ENDIF
ENDIF
ENDIF
* ENDIF
END
OUTBREAKID
HELP GEPI.HLP 21 5 +1 CONTEXT
END
MMWRWK
HELP GEPI.HLP 22 5 +1 CONTEXT
MustEnter
END
YR
HELP GEPI.HLP 23 5 +1 CONTEXT
END
REPORTED
HELP GEPI.HLP 24 5 +1 CONTEXT
IF (REPORTED <> .) AND (REPORTED - EVENTDATE < 0)
THEN HELP " ERROR: REPORTED date cannot be before EVENTDATE" 18 18
GOTO REPORTED
ENDIF
IF (REPORTED <> .) AND (UPDATED - REPORTED < 0)
THEN HELP " ERROR: REPORTED date cannot be after UPDATED " 18 18
GOTO REPORTED
ENDIF
END
OTHERDATA
HELP GEPI.HLP 25 5 +1 CONTEXT
if event = 10200
then help "For Rubella choose a letter:\n immunized pregnant \n A: yes yes \n B: yes no \n C: no yes \n D: no no\n return for no choice"10 12 keys=abcd
if result = 1
then OTHERDATA = "11"
goto imported
else
if result = 2
then OTHERDATA = "12"
goto imported
else
if result = 3
then OTHERDATA = "21"
goto imported
else
if result = 4
then OTHERDATA = "22"
goto imported
endif
endif
endif
endif
endif
if event= 10340
then help " For Rabies \n choose a letter :\n A: Bat \n B: Skunk \n C: Fox \n D: Cow \n E: Horse \n F: Dog \n G: Cat \n H: Racoon \n "10 5 keys=abcdefgh
if result = 1
then OTHERDATA = "Bat"
goto imported
else
if result = 2
then OTHERDATA = "Skunk"
goto imported
else
if result = 3
then OTHERDATA = "Fox"
goto imported
else
if result = 4
then OTHERDATA = "Cow"
goto imported
else
if result = 5
then OTHERDATA = "Horse"
goto imported
else
if result = 6
then OTHERDATA = "Dog"
goto imported
else
if result = 7
then OTHERDATA = "Cat"
goto imported
else
if result = 8
then OTHERDATA = "Raccoon"
goto imported
endif
endif
endif
endif
endif
endif
endif
endif
endif
enter
end
IMPORTED
HELP GEPI.HLP 26 5 +1 CONTEXT
COMMENT LEGAL
1 "ACQUIRED IN STATE"
2 "OUTSIDE USA"
3 "IN USA OUT OF STATE"
END
IF EVENT = 10140 and IMPORTED = .
THEN HELP "ERROR: MUST INDICATE IMPORTED STATUS FOR MEASLES\nSHOULD BE: \n 1. ACQUIRED IN STATE\n 2. ACQUIRED OUTSIDE U.S.\n 3. FROM OUT-OF-STATE\nPLEASE DOUBLE CHECK--Press ESC to continue" 30 11
GOTO IMPORTED
ENDIF
END
STATUS
HELP GEPI.HLP 27 5 +1 CONTEXT
COMMENT LEGAL
1 CONFIRMED
2 PROBABLE
3 SUSPECT
9 UNKNOWN
END
end
* gepirel.chk is made by using the NETSS menu to control entry
* if you use dos to enter you will not have use of .chk files
